home *** CD-ROM | disk | FTP | other *** search
/ Night Owl 6 / Night Owl's Shareware - PDSI-006 - Night Owl Corp (1990).iso / 001a / mskrmsrc.zip / MSNUT1.ASM < prev    next >
Assembly Source File  |  1991-10-24  |  12KB  |  590 lines
  1.        NAME    MSNUT1
  2. ; File MSNUT1.ASM
  3. ; Provides various Intel 8088 level operations, including
  4. ; display facilities (via msg buffer or DOS) for char, strings, etc.
  5. ;
  6. ; Copyright 1991, University of Waterloo.
  7. ; Copyright (C) 1991, Trustees of Columbia University in the
  8. ;  City of New York.  Permission is granted to any individual or
  9. ;  institution to use, copy, or redistribute this software as long as
  10. ;  it is not sold for profit and this copyright notice is retained.
  11. ; 
  12. ; Written by Erick Engelke of the University of Waterloo, Waterloo, 
  13. ;  Ontario, Canada,
  14. ;  and by Joe R. Doupnik, Utah State University, 
  15. ;  jrd@cc.usu.edu, jrd@usu.Bitnet.
  16. ;
  17. ; Edit history
  18. ; 6 Sept 1991 v3.11
  19. ; Last Edit
  20. ; 6 Sept 1991
  21.  
  22. cr    equ    0dh
  23. lf    equ    0ah
  24. conout    equ    2
  25. dos    equ    21h
  26.  
  27. BIOSCLK    equ    046ch
  28. HI_MAX    equ    018h
  29. LO_MAX    equ     0b0h
  30.  
  31. _TEXT    SEGMENT  WORD PUBLIC 'CODE'
  32. _TEXT    ENDS
  33. _DATA    SEGMENT  WORD PUBLIC 'DATA'
  34. _DATA    ENDS
  35. CONST    SEGMENT  WORD PUBLIC 'CONST'
  36. CONST    ENDS
  37. _BSS    SEGMENT  WORD PUBLIC 'BSS'
  38. _BSS    ENDS
  39. DGROUP    GROUP    CONST, _BSS, _DATA
  40.     ASSUME  CS: _TEXT, DS: DGROUP, SS: DGROUP
  41.  
  42. _DATA    SEGMENT
  43.     extrn    _doslevel:word, _msgcnt:word, _msgbuf:byte,_display_mode:byte
  44. _DATA    ENDS
  45.  
  46. _TEXT    segment
  47.  
  48.         ; Compute 1's-complement sum of data buffer
  49.         ; unsigned checksum( unsigned word *buf, unsigned cnt)
  50.  
  51.     public    _checksum
  52. _checksum proc    near
  53.     push    bp
  54.     mov    bp,sp
  55.     push    si
  56.     push    bx
  57.     push    cx
  58.     push    dx
  59.         mov     si,[bp+4+0]        ; offset of data to be checked
  60.     mov     cx,[bp+4+2]        ; cx = cnt
  61.     mov    bl,cl
  62.     shr     cx,1            ; group into words
  63.     xor    dx,dx            ; set checksum to 0
  64.         cld
  65.     jcxz    chk3
  66.         clc
  67. chk1:    lodsw
  68.     adc    dx,ax
  69.     loop    chk1
  70.                     ; resolve remainder
  71. chk2:    adc     dx,0
  72.         jc    chk2
  73. chk3:    and    bl,1
  74.     jz    chk5
  75.         xor     ah,ah
  76.     lodsb
  77.         clc
  78.         add     dx,ax
  79. chk4:    adc     dx,0
  80.     jc    chk4
  81. chk5:    mov    ax,dx            ; result into ax
  82.         or      ax,ax
  83.     jnz    chk6
  84.         mov     ax,0ffffh
  85. chk6:    pop    dx
  86.     pop    cx
  87.     pop    bx
  88.     pop    si
  89.     pop    bp
  90.     ret
  91. _checksum endp
  92.  
  93. ;  intel - convert intel <--> bigendian
  94. ;
  95. ;*************************************************************************
  96. ;  USAGE:  ULONG intel( ULONG val )
  97. ;          - convert to intel format
  98. ;*************************************************************************
  99.     public    _intel
  100. _intel    proc    near
  101.     push    bp
  102.     mov    bp,sp
  103.     mov    AX,[BP+4+2]
  104.     mov    DX,[BP+4+0]
  105.     xchg    AL, AH
  106.     xchg    DL, DH
  107.     pop    bp
  108.     ret
  109. _intel    endp
  110. ;*************************************************************************
  111. ;  USAGE:  UINT intel16( UINT val )
  112. ;          - convert to intel format
  113. ;*************************************************************************
  114.     public    _intel16
  115. _intel16 proc    near
  116.     push    bp
  117.     mov    bp,sp
  118.     mov    AX,[BP+4+0]
  119.     xchg    AL,AH
  120.     pop    bp
  121.     ret
  122. _intel16 endp
  123.  
  124. ; int ourmod(int top, int bottom)
  125.     public    _ourmod
  126. _ourmod    proc    near
  127.     push    bp
  128.     mov    bp,sp
  129.     push    bx
  130.     mov    ax,[bp+4+0]        ; top number
  131.     mov    bx,[bp+4+2]        ; bottom number (radix)
  132.     xor    dx,dx
  133.     or    bx,bx            ; bottom is zero?
  134.     jz    ourmod1            ; yes, return zero
  135.     div    bx
  136. ourmod1:mov    ax,dx            ; return remainder
  137.     pop    bx
  138.     pop    bp
  139.     ret
  140. _ourmod    endp
  141.  
  142. ; int ourdiv(int top, int bottom)
  143.     public    _ourdiv
  144. _ourdiv    proc    near
  145.     push    bp
  146.     mov    bp,sp
  147.     push    bx
  148.     mov    ax,[bp+4+0]        ; top
  149.     mov    bx,[bp+4+2]        ; bottom
  150.     xor    dx,dx
  151.     or    bx,bx            ; divide by zero?
  152.     jz    outdiv1            ; z = yes, divide by one
  153.     div    bx
  154. outdiv1:pop    bx
  155.     pop    bp            ; quotient is returned in ax
  156.     ret
  157. _ourdiv    endp
  158.  
  159. ; int ourlmod(long top, int bottom)
  160.     public    _ourlmod
  161. _ourlmod proc    near
  162.     push    bp
  163.     mov    bp,sp
  164.     push    bx
  165.     mov    ax,[bp+4+0]        ; top lower 16 bits
  166.     mov    dx,[bp+4+2]        ; top upper 16 bits
  167.     mov    bx,[bp+4+4]        ; bottom
  168.     or    bx,bx            ; zero?
  169.     jz    outlmo1            ; z = yes divide by 2^16 and quit
  170.     div    bx
  171. outlmo1:mov    ax,dx            ; return remainder in ax
  172.     pop    bx
  173.     pop    bp
  174.     ret
  175. _ourlmod endp
  176.  
  177. ; int ourldiv(long top, int bottom)
  178.     public    _ourldiv
  179. _ourldiv proc    near
  180.     push    bp
  181.     mov    bp,sp
  182.     push    bx
  183.     mov    ax,[bp+4+0]        ; top lower 16 bits
  184.     mov    dx,[bp+4+2]        ; top upper 16 bits
  185.     mov    bx,[bp+4+4]        ; bottom
  186.     cmp    dx,bx            ; about to overflow?
  187.     jae    ourldiv1        ; ae = yes, return 0xffffh
  188.     div    bx
  189.     xor    dx,dx            ; clear remainder (high order ret)
  190.     pop    bx
  191.     pop    bp            ; quotient is returned in dx:ax
  192.     ret
  193. ourldiv1:mov    ax,0ffffh        ; overflow indication
  194.     xor    dx,dx            ; clear high order
  195.     pop    bx
  196.     pop    bp
  197.     ret
  198. _ourldiv endp
  199.  
  200. ; long ourlmul(long top, int bottom)
  201.     public    _ourlmul
  202. _ourlmul proc    near
  203.     push    bp
  204.     mov    bp,sp
  205.     push    bx
  206.     push    cx
  207.     mov    ax,[bp+4+2]        ; top upper 16 bits
  208.     mov    bx,[bp+4+4]        ; bottom
  209.     mul    bx
  210.     mov    cx,ax            ; save product (no overflow noted)
  211.     mov    ax,[bp+4+0]        ; top lower 16 bits
  212.     mul    bx
  213.     adc    dx,cx            ; new upper 16 bits
  214.     pop    cx
  215.     pop    bx
  216.     mov    sp,bp
  217.     pop    bp            ; long product is returned in dx:ax
  218.     ret
  219. _ourlmul endp
  220.  
  221. ; void * bcopy(src, dest, count)
  222. ; void *dest, *src;
  223. ; size_t count;
  224. ; copy count bytes from src to dest
  225.     public    _bcopy
  226. _bcopy proc    near
  227.     push    bp
  228.     mov    bp,sp
  229.     push    es
  230.     push    si
  231.     push    di
  232.     push    cx
  233.     mov    ax,ds            ; set to same data segment
  234.     mov    es,ax
  235.     mov    si,[bp+4+0]        ; offset of source
  236.     mov    di,[bp+4+2]        ; offset of destination
  237.     mov    cx,[bp+4+4]        ; count
  238.     cld
  239.     push    di            ; push dest address for return
  240.     jcxz    bcopy2            ; z = nothing to copy
  241.     or    di,di            ; is destination NULL?
  242.     jz    bcopy2            ; z = yes, don't do a thing
  243.     cmp    si,di            ; is source after destination?
  244.     ja    bcopy1            ; a = yes, no overlap problem
  245.     je    bcopy2            ; e = same place, do nothing
  246.     add    di,cx            ; start at the ends
  247.     dec    di
  248.     add    si,cx
  249.     dec    si
  250.     std                ; work backward
  251. bcopy1:    rep    movsb
  252. bcopy2:    pop    ax            ; recover return destination
  253.     cld
  254.     pop    cx
  255.     pop    di
  256.     pop    si
  257.     pop    es
  258.     mov    sp,bp
  259.     pop    bp
  260.     ret
  261. _bcopy endp
  262.  
  263. ; void * memset(dest, c, count)
  264. ; void *dest;
  265. ; char c;
  266. ; size_t count;
  267.     public    _memset
  268. _memset    proc    near
  269.     push    bp
  270.     mov    bp,sp
  271.     push    es
  272.     push    di
  273.     push    cx
  274.     mov    ax,ds            ; setup data segment
  275.     mov    es,ax
  276.     mov    di,[bp+4+0]        ; offset of destination
  277.     or    di,di            ; is it NULL?
  278.     jz    memset1            ; z = yes, don't do a thing
  279.     push    di            ; save dest for return
  280.     mov    al,[bp+4+2]        ; byte of character c
  281.     mov    ah,al
  282.     mov    cx,[bp+4+4]        ; count
  283.     jcxz    memset1            ; z = do nothing
  284.     cld
  285.     shr    cx,1
  286.     jnc    memset2
  287.     stosb
  288. memset2:rep    stosw
  289.     pop    ax            ; return pointer to destination
  290. memset1:pop    cx
  291.     pop    di
  292.     pop    es
  293.     mov    sp,bp
  294.     pop    bp
  295.     ret
  296. _memset    endp
  297.  
  298. ;
  299. ;  Timer routines - use set_*timeout to receive a clock value which
  300. ;                   can later be tested by calling chk_timeout with
  301. ;                   that clock value to determine if a timeout has
  302. ;                   occurred.  chk_timeout returns 0 if NOT timed out.
  303. ;
  304. ;
  305. ;  Usage :
  306. ;           long set_timeout( int seconds );
  307. ;           long set_ttimeout( int pc_ticks );
  308. ;           int chk_timeout( long value );
  309. ;
  310. ;  (c) 1990 University of Waterloo,
  311. ;           Faculty of Engineering,
  312. ;           Engineering Microcomputer Network Development Office
  313. ;
  314. ;  version
  315. ;
  316. ;    0.1    7-Nov -1990   E. P. Engelke
  317. ;
  318. ;
  319.  
  320.     public    _set_ttimeout
  321. _set_ttimeout proc    near
  322.     push    bp
  323.     mov    bp,sp
  324.     push    es
  325.         xor     AX, AX
  326.         cwd
  327.         mov     ES, AX
  328.         mov     AX, [BP+4+0]
  329.     pushf
  330.     cli
  331.         add     AX, ES:[BIOSCLK+0];
  332.         adc     DX, ES:[BIOSCLK+2];
  333.     popf
  334.     pop    es
  335.     pop    bp
  336.     ret
  337. _set_ttimeout endp
  338.  
  339.     public    _set_timeout
  340. _set_timeout proc near
  341.     push    bp
  342.     mov    bp,sp
  343.     push    es
  344.     push    cx
  345.     xor    AX, AX            ; reference low memory
  346.     mov    ES, AX
  347.  
  348.     mov    AX,[BP+4+0]        ; seconds
  349.     xor    dx,dx
  350.     mov    cx,1165
  351.     mul    cx            ; 1165/64 = 18.203...
  352.     mov    CX,6
  353. tmp:    shr    DX,1
  354.     rcr    AX,1
  355.     loop    tmp
  356.     pushf
  357.     cli
  358.     add    AX,ES:[BIOSCLK+0]
  359.     adc    DX,ES:[BIOSCLK+2]
  360.     popf
  361.     pop    cx
  362.     pop    es
  363.     pop    bp
  364.     ret
  365. _set_timeout    endp
  366.  
  367.     public    _chk_timeout
  368. _chk_timeout    proc near
  369.     push    bp
  370.     mov    bp,sp
  371.     push    cx
  372.     push    es
  373.     xor    AX, AX
  374.     mov    ES, AX
  375.     pushf
  376.     cli
  377.     mov    CX,ES:[BIOSCLK+0]
  378.     mov    BX,ES:[BIOSCLK+2]
  379.     popf
  380.     pop    es
  381.     mov    AX,[BP+4+0]        ; timeout value
  382.     mov    DX,[BP+4+2]
  383.     cmp    DX,BX            ; if timeout < clock, has expired
  384.         jb      ret_tru
  385.     cmp    AX, CX
  386.         jbe      ret_tru
  387.                     ; may have gone over by one day
  388.     sub    AX, LO_MAX
  389.     sbb    DX, HI_MAX
  390.     jc    ret_fal            ; c = nope, timeout is today
  391.                     ; test timeout new values
  392.     cmp    DX, BX
  393.     jb    ret_tru
  394.     cmp    AX, CX
  395.     ja    ret_fal
  396. ret_tru:mov    AX, 1            ; say have timed out
  397.     pop    cx
  398.     pop    bp
  399.     ret
  400.  
  401. ret_fal:xor    AX, AX            ; say have not timed out
  402.     pop    cx
  403.     pop    bp
  404.     ret
  405. _chk_timeout    endp
  406.  
  407. ; unsigned long realclock(void)
  408.     public    _realclock
  409. _realclock    proc near        ; get Bios time of day dword
  410.     push    es
  411.     xor    ax,ax            ; reference low memory
  412.     mov    es,ax
  413.     pushf
  414.     cli
  415.     mov    ax,es:[BIOSCLK+0]    ; return Bios time of day tick count
  416.     mov    dx,es:[BIOSCLK+2]
  417.     popf
  418.     pop    es
  419.     ret
  420. _realclock endp
  421.  
  422. ; void _chkstk()
  423. ; {
  424. ;  ;
  425. ; }
  426.     public    __chkstk, __aNchkstk
  427. __chkstk proc    near            ; MSC v5.1
  428. __aNchkstk equ    this byte        ; MSC v6.00
  429.     pop    bx            ; pop return address
  430.     sub    sp,ax            ; down adjust stack pointer
  431.     jmp    bx            ; return the no-stack way
  432. __chkstk endp
  433.  
  434.  
  435. ; void 
  436. ; outch(char ch)
  437. ; Sends character to the screen via the msgbuf buffer if operating at
  438. ; interrupt level, or via DOS if operating at task level.
  439.     public    _outch
  440. _outch    proc    near
  441.     push    bp
  442.     mov    bp,sp
  443.     push    ax
  444.     push    bx
  445.     cmp    _display_mode,0        ; quiet screen?
  446.     je    outch3            ; e = yes
  447.     mov    al,[bp+4]        ; get the character
  448.     cmp    _doslevel,0        ; at DOS task level?
  449.     je    outch1            ; e = no
  450.     mov    ah,conout        ; use DOS
  451.     push    dx
  452.     mov    dl,al
  453.     int    dos
  454.     pop    dx
  455.     jmp    short outch3
  456. outch1:    cmp    _msgcnt,256        ; is buffer filled?
  457.     ja    outch3            ; a = yes, discard this byte
  458.     mov    bx,_msgcnt
  459.     mov    _msgbuf[bx],al
  460.     inc    _msgcnt
  461. outch3:    pop    bx
  462.     pop    ax
  463.     mov    sp,bp
  464.     pop    bp
  465.     ret
  466. _outch    endp
  467.  
  468.  
  469. ; void 
  470. ; outsn(char * string, int count)
  471. ; display counted string
  472.     public    _outsn
  473. _outsn    proc    near
  474.     push    bp
  475.     mov    bp,sp
  476.     push    ax
  477.     push    si
  478.     mov    si,[bp+4]        ; string address
  479.     mov    cx,[bp+4+2]        ; string length
  480.     cld
  481. outsn1:    lodsb
  482.     or    al,al
  483.         jz      outsn2
  484.         cmp     al,cr            ; convert cr to cr lf
  485.         jnz     outsn3
  486.         push    ax
  487.         call    _outch
  488.         pop     ax
  489. outsn3: push    ax
  490.         call    _outch
  491.         pop     ax
  492.     loop    outsn1
  493. outsn2:    pop    si
  494.     pop    ax
  495.     mov    sp,bp
  496.     pop    bp
  497.     ret
  498. _outsn    endp
  499.  
  500. ; void 
  501. ; outs(char * string)
  502. ; display asciiz string
  503.     public    _outs
  504. _outs    proc    near
  505.     push    bp
  506.     mov    bp,sp
  507.     push    ax
  508.     push    si
  509.     mov    si,[bp+4]        ; asciiz string address
  510.     cld
  511. outs1:    lodsb
  512.         or      al,al
  513.     jz     outs2
  514.         cmp     al,cr            ; convert cr to cr lf
  515.         jnz     outs3
  516.         push    ax
  517.         call    _outch
  518.         pop     ax
  519. outs3:  push    ax
  520.         call    _outch
  521.         pop     ax
  522.     jmp    outs1
  523. outs2:    pop    si
  524.     pop    ax
  525.     mov    sp,bp
  526.     pop    bp
  527.     ret
  528. _outs    endp
  529.  
  530. ; void
  531. ; outhex(char c)
  532. ; display char in hex
  533.     public _outhex
  534. _outhex    proc    near
  535.     push    bp
  536.     mov    bp,sp
  537.     push    ax
  538.         mov     ax,[bp+4]        ; incoming character
  539.         mov     cl, 4
  540.         shr     al, cl
  541.         call    outh
  542.         mov     ax,[bp+4]
  543.         call    outh
  544.     pop    ax
  545.     mov    sp,bp
  546.     pop    bp
  547.     ret
  548.  
  549. ; worker for outhex
  550. outh    proc    near
  551.     and     al,0fh
  552.         cmp     al,9
  553.         jbe     outh1
  554.         add     al,'A' - '9' - 1
  555. outh1:    add     al,'0'
  556.         push    ax
  557.         call    _outch
  558.         pop     ax
  559.         ret
  560. outh    endp
  561. _outhex    endp
  562.  
  563. ; output a string of hex chars
  564. ; void
  565. ; outhexes(char * string, int count )
  566.     public    _outhexes
  567. _outhexes proc    near
  568.     push    bp
  569.     mov    bp,sp
  570.     push    ax
  571.     push    si            ; preserve such things
  572.     mov    si,[bp+4]        ; get string pointer
  573.     mov    cx,[bp+4+2]        ; get char count
  574.     cld
  575. outhexs1:lodsb                ; read a byte
  576.     push    cx            ; save loop counter
  577.     push    ax
  578.     call    _outhex            ; display as hex pair
  579.     add    sp,2            ; clean stack
  580.     pop    cx
  581.     loop    outhexs1        ; do count's worth
  582.     pop    si
  583.     pop    ax
  584.     mov    sp,bp
  585.     pop    bp
  586.     ret
  587. _outhexes endp
  588. _TEXT    ends
  589.         end
  590.